=============
javaWhere.bat: Contiene todos los comandos para usar JAVA
=============

=============
java.bat
=============

:: java.bat ==> Ejecuta un archivo .class luego de encontrar JAVA.exe
@echo off

call java_SET
if ("")==("%javaWhere%") goto _out
"%javaWhere%\java.exe" -cp . %1 %2 %3 %4 %5 %6 %7 %8 %9

goto _out

:_out
:: java.bat ==> Fin de archivo

=============
javac.bat
=============

:: javac.bat ==> Compila un archivo .java luego de encontrar JAVAC.exe
:: - "%ProgramFiles%\Java\jdk1.7.0_%2\jre\bin\javac.exe CLASE.java (con el .java)
@echo off

call java_SET
if ("")==("%javaWhere%") goto _out
"%javaWhere%\javac.exe" -cp . %1 %2 %3 %4 %5 %6 %7 %8 %9

:_out
:: javac.bat ==> Fin de archivo

=============
javadoc.bat
=============

:: java.bat ==> Encuentra y ejecuta JAVADOC.exe
@echo off

call java_SET
if ("")==("%javaWhere%") goto _out
"%javaWhere%\javadoc.exe" -cp . %1 %2 %3 %4 %5 %6 %7 %8 %9

goto _out
:_out
:: java.bat ==> Fin de archivo

=============
java_SET.bat
=============

:: java_SET.bat ==> Establece el valor de javaWhere para encontrar JAVA.exe
@echo off

:: OJO: sin las comillas ("")==("%javaWhere%") se revienta
:: - es lógico: %ProgramFiles% contiene espacios ...

if not ("")==("%javaWhere%") goto _out
if   (%1)==(+++)          goto _doit

:_recursion
::                                                              0  1     2
for %%d in (1 2 3) do for %%u in (0 1 2 3 4 5 6 7 8 9) do call %0 +++ %%d%%u
if ("")==("%javaWhere%") goto _NO_NO
goto _out

:_NO_NO
    echo [%0] FALTA javac.exe
goto _out

:_doit
    if exist "%ProgramFiles%\Java\jdk1.7.0_%2\bin\java.exe"           goto _jdk
    if exist "%ProgramFiles%\Java\jdk1.7.0_%2\jre\bin\java.exe"       goto _jdk_jre

    if exist "%ProgramFiles(x86)%\Java\jdk1.7.0_%2\bin\java.exe"      goto _jdk_32
    if exist "%ProgramFiles(x86)%\Java\jdk1.7.0_%2\jre\bin\java.exe"  goto _jdk_jre_32
goto _out

:_jdk
    set javaWhere=%ProgramFiles%\Java\jdk1.7.0_%2\bin
    echo [jdk] [%javaWhere%]
goto _out

:_jdk_jre
    set javaWhere=%ProgramFiles%\Java\jdk1.7.0_%2\jre\bin
    echo [jdk_jre] [%javaWhere%]
goto _out

:_jdk_32
    set javaWhere=%ProgramFiles(x86)%\Java\jdk1.7.0_%2\bin
    echo [jdk_32] [%javaWhere%]
goto _out

:_jdk_jre_32
    set javaWhere=%ProgramFiles(x86)%\Java\jdk1.7.0_%2\jre\bin
    echo [jdk_jre_32] [%javaWhere%]
goto _out

:_out
:: echo [%2][javaWhere]=[%javaWhere%]
:: java_SET.bat ==> Fin de archivo

=============